home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib12.dsk / PILLAR MUNCH.bas < prev    next >
BASIC Source File  |  2023-02-26  |  13KB  |  311 lines
  1. 1  REM ***********************
  2. 2  REM *    PILLAR MUNCH     *
  3. 3  REM * BY RICHARD NEDBAL   *
  4. 4  REM * COPYRIGHT (C) 1983  *
  5. 5  REM * BY MICROSPARC, INC. *
  6. 6  REM * LINCOLN, MA 01773   *
  7. 7  REM ***********************
  8. 10  IF  PEEK(104) = 64  THEN 40
  9. 20  POKE 103,1: POKE 104,64: POKE 16384,0
  10. 30  PRINT  CHR$(4);"RUN PILLAR MUNCH"
  11. 40  GOSUB 3010: GOTO 2210
  12. 50 K% =  PEEK( -16384): POKE  -16368,N0%: ROT= OD%
  13. 60  IF K% = 201  THEN ND% = UP%: GOTO 100
  14. 70  IF K% = 202  THEN ND% = LT%: GOTO 100
  15. 80  IF K% = 203  THEN ND% = RT%: GOTO 100
  16. 90  IF K% = 205  THEN ND% = DN%
  17. 100  FOR Z = 0 TO GS: NEXT Z
  18. 110  IF ND% = UP%  THEN YS% = Y% -N4%:XS% = X%: GOTO 150
  19. 120  IF ND% = RT%  THEN XS% = X% +N4%:YS% = Y%: GOTO 150
  20. 130  IF ND% = DN%  THEN YS% = Y% +N4%:XS% = X%: GOTO 150
  21. 140  IF ND% = LT%  THEN XS% = X% -N4%:YS% = Y%
  22. 150  GOSUB 470
  23. 160  IF HIT% = N1%  THEN X = X%:Y = Y%: GOTO 970
  24. 170  IF K% = 160  THEN X = X%:Y = Y%: GOTO 1700
  25. 180  REM  ERASE HEAD
  26. 190  HCOLOR= N0%: DRAW 8 AT X%,Y%
  27. 200  IF J = N1%  THEN J = N0%: GOTO 230
  28. 210 J = N1%
  29. 220  REM  ERASE LAST SEGMENT
  30. 230  DRAW 8 AT LX%,LY%
  31. 240  IF LR% = N0%  THEN LX% = LX% +N7%: GOTO 280
  32. 250  IF LR% = DN%  THEN LY% = LY% +N7%: GOTO 280
  33. 260  IF LR% = LT%  THEN LX% = LX% -N7%: GOTO 280
  34. 270  IF LR% = UP%  THEN LY% = LY% -N7%
  35. 280  IF CNR%(0,1) = LX%  AND CNR%(0,2) = LY%  THEN LR% = CNR%(0,0): GOTO 300
  36. 290  GOTO 340
  37. 300  FOR Z = N0% TO CM%
  38. 310 CNR%(Z,0) = CNR%(Z +N1%,0):CNR%(Z,1) = CNR%(Z +N1%,1):CNR%(Z,2) = CNR%(Z +N1%,2)
  39. 320  NEXT 
  40. 330 CM% = CM% -N1%
  41. 340  HCOLOR= N3%: ROT= ND%: DRAW 4 AT X%,Y%
  42. 350  REM  DRAW NEW HEAD
  43. 360  IF ND% < >OD%  THEN CNR%(CM%,0) = ND%:CNR%(CM%,1) = X%:CNR%(CM%,2) = Y%:CM% = CM% +N1%:OD% = ND%: ROT= ND%
  44. 370  IF ND% = RT%  THEN X% = X% +N7%: GOTO 410
  45. 380  IF ND% = DN%  THEN Y% = Y% +N7%: GOTO 410
  46. 390  IF ND% = LT%  THEN X% = X% -N7%: GOTO 410
  47. 400  IF ND% = UP%  THEN Y% = Y% -N7%
  48. 410  DRAW 1 AT X%,Y%
  49. 420  IF J = N1%  THEN  DRAW 2 AT X%,Y%: GOTO 440
  50. 430  DRAW 3 AT X%,Y%
  51. 440 LCTR% = LCTR% +N1%: IF LCTR% = LMAX%  THEN LCTR% = N0%: ROT= N0%: HCOLOR= N0%: DRAW 5 AT X3,Y3:BX = N0%: HCOLOR= N3%:X = X%:Y = Y%: GOTO 840
  52. 450 BCTR% = BCTR% +N1%: IF BCTR% = BMAX%  THEN BCTR% = N0%:X = X%:Y = Y%: GOTO 1910
  53. 460  GOTO 50
  54. 470  IF YS% <C1%  THEN ADR% =  INT(YS%/N8%) *C2% +C3% +(YS%/N8% - INT(YS%/N8%)) *C3% + INT(XS%/N7%)
  55. 480  IF YS% > = C1%  AND YS% <C2%  THEN YS% = YS% -C1%:ADR% =  INT(YS%/N8%) *C2% +C4% +(YS%/N8% - INT(YS%/N8%)) *C3% + INT(XS%/N7%)
  56. 490  IF YS% > = C2%  THEN YS% = YS% -C2%:ADR% =  INT(YS%/N8%) *C2% +C5% +(YS%/N8% - INT(YS%/N8%)) *C3% + INT(XS%/N7%)
  57. 500 HIT% = N0%
  58. 510  IF  PEEK(ADR%)  THEN HIT% = N1%
  59. 520  RETURN 
  60. 530  TEXT : HOME : INPUT "SELECT DIFFICULTY (1-6) ";DD
  61. 540  IF DD <N1%  OR DD >N6  THEN  GOTO 530
  62. 550 BFLY = N0%: HGR 
  63. 560  SCALE= N1%: ROT= N0%: HCOLOR= N3%: HOME :SEG = N5:BCTR% = N0%:LCTR% = N0%:CM% = N0%: VTAB 21:OD% = N0%:ND% = N0%
  64. 570  IF DD = N1%  THEN BMAX% = 1000:LMAX% = 1000:SMAX = 10:BIRD = N0%
  65. 580  IF DD = N2%  THEN BMAX% = 1000:LMAX% = 150:SMAX = 20:BIRD = N0%
  66. 590  IF DD = N3%  THEN BMAX% = 40:LMAX% = 40:SMAX = 30:BIRD = N1%
  67. 600  IF DD = N4%  THEN BMAX% = 30:LMAX% = 30:SMAX = 50:BIRD = N1%
  68. 610  IF DD = N5  THEN BMAX% = 20:LMAX% = 20:SMAX = 75:BIRD = N1%
  69. 620  IF DD = N6  THEN BMAX% = 15:LMAX% = 15:SMAX = 99:BIRD = N1%
  70. 630  REM  DRAW BORDER & CATERPILLAR
  71. 640 X = 129:Y = 70:J = N1%
  72. 650  DRAW 1 AT X,Y: DRAW 2 AT X,Y:X1 = X -N7%
  73. 660  FOR Z = 0 TO 4
  74. 670  DRAW 4 AT X1,Y
  75. 680 X1 = X1 -N7%
  76. 690  NEXT Z
  77. 700 LR% = N0%:LX% = 94:LY% = 70
  78. 710  FOR Z = 0 TO 20
  79. 720 CNR%(Z,0) = N0%:CNR%(Z,1) = N0%:CNR%(Z,2) = N0%
  80. 730  NEXT Z
  81. 740  HPLOT 5,2 TO 274,2 TO 274,159 TO 5,159 TO 5,2
  82. 750  HPLOT 6,3 TO 273,3 TO 273,158 TO 6,158 TO 6,3
  83. 760  IF DD = N2%  THEN  HPLOT 70,32 TO 70,122 TO 76,122 TO 76,32 TO 70,32 TO 73,32 TO 73,122: HPLOT 203,60 TO 203,94 TO 209,94 TO 209,60 TO 203,60 TO 206,60 TO 206,94
  84. 770  IF DD = N3%  THEN  HPLOT 70,32 TO 70,122 TO 76,122 TO 76,32 TO 70,32 TO 73,32 TO 73,122: HPLOT 203,32 TO 203,122 TO 209,122 TO 209,32 TO 203,32 TO 206,32 TO 206,122
  85. 780  IF DD = N4%  THEN  HPLOT 139,32 TO 70,32 TO 70,122 TO 139,122 TO 139,116 TO 76,116 TO 76,38 TO 139,38 TO 139,32 TO 139,35 TO 73,35 TO 73,119 TO 139,119: HPLOT 203,60 TO 203,94 TO 209,94 TO 209,60 TO 203,60 TO 206,60 TO 206,94
  86. 790  IF DD = N5  THEN  HPLOT 139,32 TO 70,32 TO 70,122 TO 139,122 TO 139,116 TO 76,116 TO 76,38 TO 139,38 TO 139,32 TO 139,35 TO 73,35 TO 73,119 TO 139,119: HPLOT 203,32 TO 203,122 TO 209,122 TO 209,32 TO 203,32 TO 206,32 TO 206,122
  87. 800  IF DD = N6  THEN  HPLOT 139,32 TO 70,32 TO 70,122 TO 139,122 TO 139,116 TO 76,116 TO 76,38 TO 139,38 TO 139,32 TO 139,35 TO 73,35 TO 73,119 TO 139,119: HPLOT 133,18 TO 209,18 TO 209,136 TO 133,136 TO 133,130 TO 203,130 TO 203,24 TO 133,24 TO 133,18 TO 133,21 TO 206,21 TO 206,133 TO 133,133
  88. 810  REM  SELECT RANDOM LEAF
  89. 820  FOR Z = 1 TO 5
  90. 830 RL = N1%
  91. 840 X1 =  INT( RND(1) *279):Y1 =  INT( RND(1) *159)
  92. 850 X1 =  INT(X1/7) *7 +3:Y1 =  INT(Y1/7) *7
  93. 860  IF X1 <10  OR X1 >269  THEN  GOTO 840
  94. 870  IF Y1 <7  OR Y1 >147  THEN  GOTO 840
  95. 880 XS% = X1:YS% = Y1: ROT= N0%
  96. 890  GOSUB 470
  97. 900  IF HIT% = N1%  THEN  GOTO 840
  98. 910  IF BX = N1%  THEN BX = N0%: DRAW 6 AT X1,Y1:XS% = X:YS% = Y:X% = X:Y% = Y:F = 20:D = 1: GOSUB 2780: GOSUB 2780: GOTO 50
  99. 920  DRAW 5 AT X1,Y1:XS% = X:YS% = Y:X3 = X1:Y3 = Y1: GOSUB 2810: IF RL = N1%  THEN RL = N0%: NEXT Z
  100. 930  HOME : VTAB 23: PRINT "YOUR BEST:DIF= ";DF;" SEGS= ";SF;" BFLYS= ";MF
  101. 940  VTAB 21: PRINT "THIS GAME:DIF= ";DD;" SEGS= ";SEG;" BFLYS= ";BFLY
  102. 950 X% = X:Y% = Y: GOTO 50
  103. 960  REM : WHAT DID WE HIT%?
  104. 970 ID =  PEEK(ADR%): REM   LEAF=62 OR 8
  105. 980  IF ID = 62  OR ID = 8  THEN  GOTO 1180
  106. 990  REM  END OF GAME
  107. 1000  GOSUB 2950
  108. 1010  REM 
  109. 1020  IF BFLY >MF  AND DD > = DF  THEN  GOTO 1050
  110. 1030  IF BFLY = MF  AND DD > = DF  AND SEG >SF  THEN  GOTO 1050
  111. 1040  GOTO 1150
  112. 1050 MF = BFLY:SF = SEG:DF = DD
  113. 1060  IF NPRES = N1%  THEN  GOTO 1930
  114. 1070  PRINT D$;"APPEND HIGH SCORES"
  115. 1080  PRINT D$;"WRITE HIGH.SCORES"
  116. 1090 SPAC = 19 -NL:SD = 8 -DL
  117. 1100  IF SF <10  THEN  PRINT NAME$; SPC( SPAC);DT$; SPC( SD);" ";DF;"  ";SF;"   ";MF
  118. 1110  IF SF > = 10  THEN  PRINT NAME$; SPC( SPAC);DT$; SPC( SD);" ";DF;"  ";SF;"  ";MF
  119. 1120  PRINT D$"CLOSE": PRINT D$
  120. 1130  IF NPRES = 0  THEN NPRES = N1%: GOTO 2340
  121. 1140  TEXT : HOME : VTAB 23: PRINT "DIF= ";DF;"  SEGMENTS= ";SF;"  METAMORPHOSES= ";MF
  122. 1150  VTAB 24: PRINT "GAME OVER   PRESS ANY KEY";
  123. 1160  GET T$
  124. 1170  GOTO 530
  125. 1180  HCOLOR= N0%: DRAW 1 AT X,Y: DRAW 2 AT X,Y: DRAW 3 AT X,Y
  126. 1190  HCOLOR= N3%: ROT= ND%
  127. 1200  DRAW 1 AT X,Y
  128. 1210  FOR Z = 0 TO 10
  129. 1220 SQ =  PEEK( -16336):SQ =  PEEK( -16336)
  130. 1230  HCOLOR= N0%: FOR Z1 = 0 TO GS: NEXT Z1
  131. 1240  IF J = N1%  THEN J = N0%: DRAW 2 AT X,Y: GOTO 1260
  132. 1250 J = N1%: DRAW 3 AT X,Y
  133. 1260  HCOLOR= N3%: FOR Z1 = 0 TO GS: NEXT Z1
  134. 1270  IF J = N1%  THEN  DRAW 2 AT X,Y: GOTO 1290
  135. 1280  DRAW 3 AT X,Y
  136. 1290  NEXT Z
  137. 1300  REM : ERASE LEAF
  138. 1310  HCOLOR= N0%
  139. 1320  IF ND% = RT%  THEN X3 = X +N7%:Y3 = Y
  140. 1330  IF ND% = LT%  THEN X3 = X -N7%:Y3 = Y
  141. 1340  IF ND% = UP%  THEN Y3 = Y -N7%:X3 = X
  142. 1350  IF ND% = DN%  THEN Y3 = Y +N7%:X3 = X
  143. 1360  DRAW 8 AT X3,Y3
  144. 1370 SEG = SEG +N1%
  145. 1380  IF LR% = N0%  THEN LX% = LX% -N7%
  146. 1390  IF LR% = DN%  THEN LY% = LY% -N7%
  147. 1400  IF LR% = LT%  THEN LX% = LX% +N7%
  148. 1410  IF LR% = UP%  THEN LY% = LY% +N7%
  149. 1420  HCOLOR= N3%: ROT= LR%
  150. 1430  DRAW 4 AT LX%,LY%
  151. 1440  IF SEG = SMAX  THEN  GOTO 1490
  152. 1450  HOME : VTAB 23: PRINT "YOUR BEST:DIF= ";DF;" SEGS= ";SF;" BFLYS= ";MF
  153. 1460  VTAB 21: PRINT "THIS GAME:DIF= ";DD;" SEGS= ";SEG;" BFLYS= ";BFLY
  154. 1470 LCTR% = N0%
  155. 1480  GOTO 840
  156. 1490  HGR :BFLY = BFLY +N1%: ROT= N0%: GOSUB 2870
  157. 1500 X2 = 136:Y2 = 77
  158. 1510  FOR Z = 0 TO 25
  159. 1520  HCOLOR= N3%: DRAW 7 AT X2,Y2
  160. 1530  FOR Z1 = 0 TO GS *2: NEXT Z1
  161. 1540  HCOLOR= N0%: DRAW 7 AT X2,Y2
  162. 1550 R1 =  INT( RND(1) *3):R2 =  INT( RND(1) *3)
  163. 1560  IF R1 = 0  THEN X2 = X2 +7
  164. 1570  IF R1 = 1  THEN X2 = X2 -7
  165. 1580  IF R2 = 0  THEN Y2 = Y2 +7
  166. 1590  IF R2 = 1  THEN Y2 = Y2 -7
  167. 1600  IF Y2 >154  OR Y2 <10  THEN X2 = 136:Y2 = 77: GOTO 1620
  168. 1610  IF X2 >269  OR X2 <7  THEN X2 = 136:Y2 = 77
  169. 1620  NEXT Z
  170. 1630  IF BFLY = 9  THEN  TEXT : HOME : VTAB 12: PRINT "YOU HAVE ATTAINED RANKING OF": PRINT : PRINT "***GRAND  MASTER***": PRINT : PRINT "FOR DIFFICULTY LEVEL ";DD: GOTO 1050
  171. 1640 X2 = 17:Y2 = 154: SCALE= N1%: HCOLOR= N3%
  172. 1650  FOR Z = 1 TO BFLY
  173. 1660  DRAW 7 AT X2,Y2
  174. 1670 X2 = X2 +14
  175. 1680  NEXT Z
  176. 1690  GOTO 560
  177. 1700  IF BIRD = N0%  THEN  GOTO 190
  178. 1710 X4 = X:Y4 = Y:D4 = N4%
  179. 1720  FOR Z = 1 TO 14
  180. 1730  HCOLOR= N3%
  181. 1740  IF OD% = N0%  THEN X4 = X4 +D4
  182. 1750  IF OD% = DN%  THEN Y4 = Y4 +D4
  183. 1760  IF OD% = LT%  THEN X4 = X4 -D4
  184. 1770  IF OD% = UP%  THEN Y4 = Y4 -D4
  185. 1780  IF X4 >272  OR X4 <7  THEN  GOTO 190
  186. 1790  IF Y4 >157  OR Y4 <3  THEN  GOTO 190
  187. 1800 XS% = X4:YS% = Y4:D4 = N7%: GOSUB 470
  188. 1810  IF HIT% = N1%  THEN  GOTO 1860
  189. 1820  HPLOT X4,Y4 -N1% TO X4,Y4 +N1%: HPLOT X4 -N1%,Y4 TO X4 +N1%,Y4
  190. 1830  HCOLOR= N0%: HPLOT X4,Y4 -N1% TO X4,Y4 +N1%: HPLOT X4 -N1%,Y4 TO X4 +N1%,Y4
  191. 1840  NEXT 
  192. 1850  GOTO 190
  193. 1860 ID =  PEEK(ADR%): IF ID = 24  OR ID = 65  THEN  GOTO 990
  194. 1870 X4 =  INT(X4/N7%) *N7% +3:Y4 =  INT(Y4/N7%) *7: IF OD% = DN%  THEN Y4 = Y4 +N7%
  195. 1880  HCOLOR= N0%: IF ID = 127  OR ID = 73  THEN  GOTO 1900
  196. 1890  DRAW 8 AT X4,Y4
  197. 1900  GOTO 190
  198. 1910  IF BIRD = N0%  THEN  GOTO 50
  199. 1920 BX = N1%: GOTO 840
  200. 1930  PRINT D$;"OPEN HIGH SCORES"
  201. 1940  PRINT D$;"POSITION HIGH SCORES,R";PS
  202. 1950  GOTO 1080
  203. 1960  PRINT D$;"OPEN HIGH SCORES"
  204. 1970  PRINT D$;"DELETE HIGH SCORES"
  205. 1980  PRINT D$;"OPEN HIGH SCORES"
  206. 1990  PRINT D$;"WRITE HIGH SCORES"
  207. 2000  PRINT "   HISTORICAL HIGH SCORE INFORMATION"
  208. 2010  PRINT "   *********************************"
  209. 2020  PRINT 
  210. 2030  PRINT "D = DIFFICULTY THAT WAS USED"
  211. 2040  PRINT "S = NUMBER OF BODY SEGMENTS REACHED"
  212. 2050  PRINT "M = NUMBER OF METAMORPHOSES ATTAINED"
  213. 2060  PRINT "."
  214. 2070  PRINT ".      NAME          DATE   D  S   M"
  215. 2080  PRINT "......................................."
  216. 2090  IF FF  THEN FF = 0: PRINT D$"CLOSE": RETURN 
  217. 2100  PRINT D$
  218. 2110  PRINT D$;"OPEN HIGH SCORES"
  219. 2120  PRINT D$;"READ HIGH SCORES"
  220. 2130  INPUT A$
  221. 2140  ONERR  GOTO 2170
  222. 2150  PRINT A$
  223. 2160  GOTO 2130
  224. 2170  PRINT D$
  225. 2180  VTAB 24: PRINT "ANY KEY TO CONTINUE";
  226. 2190  GET T$
  227. 2200  GOTO 2530
  228. 2210  REM 
  229. 2220  DIM CNR%(20,2),TX$(20)
  230. 2230 D$ =  CHR$(4): REM  CTRL-D
  231. 2240 N0% = 0:N1% = 1:N2% = 2:N3% = 3:N4% = 4:N5 = 5:N6 = 6:N7% = 7:N8% = 8:N9 = 9:NPRES = 0:N7 = 7:N8 = 8:RT% = 0:DN% = 16:LT% = 32:UP% = 48:C1% = 64:C2% = 128:C3% = 8192:C4% = 8232:C5% = 8272
  232. 2250  PRINT D$;"BLOAD SOUND"
  233. 2260  PRINT D$;"BLOAD METSHAPES"
  234. 2270  POKE 232,28: POKE 233,3
  235. 2280  TEXT : HOME : VTAB 10: HTAB 13: PRINT "'PILLAR MUNCH"
  236. 2290  VTAB 12: HTAB 18: PRINT "BY"
  237. 2300  VTAB 14: HTAB 11: PRINT "RICHARD A. NEDBAL": VTAB 22: PRINT "** COPYRIGHT 1983 BY MICROSPARC, INC. **"
  238. 2310  REM 
  239. 2320  FOR Z = 0 TO 4000: NEXT Z: REM  IN PLACE OF TUNE
  240. 2330 NPRES = 0
  241. 2340  TEXT : HOME :Z = N0%
  242. 2350  FOR Z = 0 TO 20
  243. 2360 TX$(Z) = " "
  244. 2370  NEXT Z
  245. 2380 Z = N0%
  246. 2390  PRINT D$;"OPEN HIGH SCORES"
  247. 2400  PRINT D$;"READ HIGH SCORES"
  248. 2410  INPUT TX$(Z)
  249. 2420  IF Z = 20 GOTO 2450
  250. 2430  ONERR  GOTO 2450
  251. 2440  PRINT TX$(Z):Z = Z +N1%: GOTO 2410
  252. 2450  POKE 216,0: REM  CLEAR ERROR
  253. 2460  PRINT D$;"CLOSE"
  254. 2470  PRINT D$
  255. 2480  VTAB 24: PRINT "PRESS ANY KEY TO CONTINUE";
  256. 2490  GET T$
  257. 2500  HOME : INPUT "ERASE HISTORICAL INFORMATION? (Y OR N)";T$
  258. 2510  IF T$ = "Y"  THEN  GOTO 1960
  259. 2520  IF NPRES = N1% GOTO 2550
  260. 2530  HOME : INPUT "YOUR NAME PLEASE: ";NAME$
  261. 2540  INPUT "TODAY'S DATE (MM-DD-YY): ";DT$
  262. 2550 GS = 0
  263. 2560 NL =  LEN(NAME$):DL =  LEN(DT$)
  264. 2570  IF DL >8  THEN  PRINT "8 OR LESS CHARACTERS PLEASE": GOTO 2540
  265. 2580  FOR Z = 0 TO 20
  266. 2590 NFILE$ =  LEFT$(TX$(Z),NL)
  267. 2600  IF NFILE$ = NAME$  THEN NPRES = N1%:PS = Z: GOTO 2630
  268. 2610  NEXT Z
  269. 2620  GOTO 1070
  270. 2630 DF$ =  MID$ (TX$(Z),29,1):SF$ =  MID$ (TX$(Z),32,3):MF$ =  MID$ (TX$(Z),36,2)
  271. 2640 DF =  VAL(DF$):SF =  VAL(SF$):MF =  VAL(MF$)
  272. 2650  HOME : INPUT "DO YOU WANT INSTRUCTIONS? (Y OR N) ";T$
  273. 2660  IF T$ = "N"  THEN  GOTO 530
  274. 2670  SPEED= 100: HOME 
  275. 2680  PRINT : PRINT "YOU ARE A CATERPILLAR TRYING TO GROW!"
  276. 2690  PRINT : PRINT "YOU EAT LEAVES TO GROW BODY SEGMENTS."
  277. 2700  PRINT : PRINT "USE THE I,J,K & M KEYS TO MOVE AROUND."
  278. 2710  PRINT : PRINT "IF YOU CAN GROW LONG ENOUGH YOU WILL"
  279. 2720  PRINT : PRINT "METAMORPHIS INTO A BUTTERFLY.....BUT"
  280. 2730  PRINT : PRINT "DON'T RUN INTO ANYTHING EXCEPT LEAVES."
  281. 2740  PRINT : PRINT : PRINT "USE THE SPACE BAR TO SPIT."
  282. 2750  VTAB 24: PRINT "PRESS ANY KEY TO CONTINUE";
  283. 2760  SPEED= 255: GET T$
  284. 2770  GOTO 530
  285. 2780  POKE 768,D: POKE 769,F
  286. 2790  CALL 770
  287. 2800  RETURN 
  288. 2810  REM  LEAF TUNE
  289. 2820 F = 150:D = 1: GOSUB 2780
  290. 2830 F = 200:D = 1: GOSUB 2780
  291. 2840 F = 200:D = 1: GOSUB 2780
  292. 2850 F = 150:D = 1: GOSUB 2780
  293. 2860  RETURN 
  294. 2870  REM  BUTTERFLY TUNE
  295. 2880 F = 20:D = 1: GOSUB 2780
  296. 2890 F = 63:D = 1: GOSUB 2780
  297. 2900 F = 100:D = 1: GOSUB 2780
  298. 2910 F = 145:D = 1: GOSUB 2780
  299. 2920 F = 100:D = 1: GOSUB 2780
  300. 2930 F = 145:D = 1: GOSUB 2780
  301. 2940  RETURN 
  302. 2950  REM  END TUNE
  303. 2960 F = 1:D = 20: GOSUB 2780
  304. 2970 F = 1:D = 20: GOSUB 2780
  305. 2980 F = 1:D = 20: GOSUB 2780
  306. 2990 F = 1:D = 200: GOSUB 2780
  307. 3000  RETURN 
  308. 3010  ONERR  GOTO 3030
  309. 3020 D$ =  CHR$(4): PRINT D$"VERIFY HIGH SCORES": RETURN 
  310. 3030  IF  PEEK(222) = 6  THEN FF = 1: GOSUB 1980: RUN 
  311. 3040  PRINT "ERROR " PEEK(222)" IN LINE " PEEK(218) +256 * PEEK(219)